所谓移植，指的是一个操作系统可以在某个微处理器或者微控制器上运行。虽然uCOS-II的大部分源代码是用C语言写成的，仍需要用C语言和汇编语言完成一些与处理器相关的代码。比如：uCOS-II在读写处理器、寄存器时只能通过汇编语言来实现。因为uCOS-II在设计的时候就已经充分考虑了可移植性，所以，uCOS-II的移植还是比较容易的。

要使uCOS-II可以正常工作，处理器必须满足以下要求：

1．处理器的C编译器能产生可重入代码。
可重入的代码指的是一段代码（如一个函数）可以被多个任务同时调用，而不必担心会破坏数据。也就是说，可重入型函数在任何时候都可以被中断执行，过一段时间以后又可以继续运行，而不会因为在函数中断的时候被其他的任务重新调用，影响函数中的数据。下面的两个例子可以比较可重入型函数和非可重入型函数：

 

程序1：可重入型函数

void swap(int *x, int *y)

{

int temp;

     temp=*x;

*x=*y;

*y=temp;

}

 

程序2：非可重入型函数

int temp;

void swap(int *x, int *y)

{

     temp=*x;

     *x=*y;

     *y=temp;

}

 

程序1中使用的是局部变量temp作为变量。通常的C编译器，把局部变量分配在栈中。所以，多次调用同一个函数，可以保证每次的temp互不受影响。而程序2中temp定义的是全局变量，多次调用函数的时候，必然受到影响。

代码的可重入性是保证完成多任务的基础，除了在C程序中使用局部变量以外，还需要C编译器的支持。笔者使用的是ARM ADS的集成开发环境，均可以生成可重入的代码。

2．在程序中可以打开或者关闭中断。
在uCOS-II中，可以通过OS_ENTER_CRITICAL()或者OS_EXIT_CRITICAL()宏来控制系统关闭或者打开中断。这需要处理器的支持,在ARM920T的处理器上，可以设置相应的寄存器来关闭或者打开系统的所有中断。

3．处理器支持中断，并且能产生定时中断（通常在10Hz~1000Hz之间）。
uCOS-II是通过处理器产生的定时器的中断来实现多任务之间的调度的。在ARM920T的处理器上可以产生定时器中断。

4．处理器支持能够容纳一定量数据的硬件堆栈。
5．处理器有将堆栈指针和其它CPU寄存器存储和读出到堆栈（或者内存）的指令。
uCOS-II进行任务调度的时候，会把当前任务的CPU寄存器存放到此任务的堆栈中，然后，再从另一个任务的堆栈中恢复原来的工作寄存器，继续运行另一个任务。所以，寄存器的入栈和出栈是uCOS-II多任务调度的基础。

图4-1说明了uC/OS的结构以及它与硬件的关系。

 

图4-1 uCOS-II硬件和软件体系结构

ARM920T处理器完全满足上述要求。接下来将介绍如何把uCOS-II移植到Samsung公司的一款ARM920T的嵌入式处理器——S3C2410X上。

步骤
1．把文件分为两类，其一是STARTUP目录下的系统初始化、配置等文件，其二是uCOS-II的全部源码，arch目录下的3个文件是和处理器架构相关的。
2．设置os_cpu.h中与处理器和编译器相关的代码
typedef unsigned char  BOOLEAN;

typedef unsigned char  INT8U;                 

typedef signed   char  INT8S;                 

typedef unsigned int   INT16U;             

typedef signed   int   INT16S;            

typedef unsigned long  INT32U;             

typedef signed   long  INT32S;         

typedef float          FP32;                 

typedef double         FP64;           

typedef unsigned int   OS_STK;              

typedef unsigned int   OS_CPU_SR;

extern int  INTS_OFF(void);  

extern void INTS_ON(void);

#define  OS_ENTER_CRITICAL()  { cpu_sr = INTS_OFF(); }

#define  OS_EXIT_CRITICAL()   { if(cpu_sr == 0) INTS_ON(); }

#define  OS_STK_GROWTH        1

 

1）与编译器相关的数据类型
因为不同的微处理器有不同的字长，所以uCOS-II的移植包括了一系列的类型定义以确保其可移植性。尤其是uCOS-II代码从不使用C的short,int和long 等数据类型，因为它们是与编译器相关的，不可移植。相反的，我们定义的整形数据结构既是可移植的又是直观的。为了方便，虽然uCOS-II不使用浮点数据，但我们还是定义了浮点数据类型。

例如，INT16U数据类型总是代表16位的无符号整数。现在，uCOS-II和用户的应用程序就可以估计出声明为该数据类型的变量的取值范围是0~65535。将uCOS-II移植到32位的处理器上也就意味着INT16U实际被声明为无符号短整形数据结构而不是无符号整数数据结构。但是，uCOS-II所处理的仍然是INT16U。

用户必须将任务堆栈的数据类型告诉给uCOS-II。这个过程是通过为OS_STK声明正确的C数据类型来完成的。我们的处理器上的堆栈成员是16位的，所以将OS_STK声明为无符号整形数据类型。所有的任务堆栈都必须用OS_STK声明数据类型。

 

2）OS_ENTER_CRITICAL()和OS_EXIT_CRITICAL()
与所有的实时内核一样，uCOS-II需要先禁止中断再访问代码的临界区，并且在访问完毕后重新允许中断。这就使得uCOS-II能够保护临界区代码免受多任务或中断服务例程（ISR）的破坏。在S3C2410X上是通过两个函数（OS_CPU_A.S）实现开关中断的。

INTS_OFF

         mrs   r0, cpsr              ; 当前 CSR

         mov   r1, r0                ; 复制屏蔽

         orr   r1, r1, #0xC0         ; 屏蔽中断位

         msr   CPSR, r1              ; 关中断(IRQ and FIQ)

         and   r0, r0, #0x80         ; 从初始CSR返回FIQ位

         mov   pc,lr                 ; 返回

 

INTS_ON

         mrs   r0, cpsr              ; 当前 CSR

         bic   r0, r0, #0xC0         ; 屏蔽中断

         msr   CPSR, r0              ; 开中断 (IRQ and FIQ)

         mov   pc,lr                 ; 返回

3）OS_STK_GROWTH
绝大多数的微处理器和微控制器的堆栈是从上往下长的。但是某些处理器是用另外一种方式工作的。uCOS-II被设计成两种情况都可以处理，只要在结构常量OS_STK_GROWTH中指定堆栈的生长方式就可以了。

置OS_STK_GROWTH为0表示堆栈从下往上长。

置OS_STK_GROWTH为1表示堆栈从上往下长。

3．用C语言编写6个操作系统相关的函数（OS_CPU_C.C）
1）OSTaskStkInit
OSTaskCreate()和OSTaskCreateExt()通过调用OSTaskStkInit()来初始化任务的堆栈结构。因此，堆栈看起来就像刚发生过中断并将所有的寄存器保存到堆栈中的情形一样。图4-2显示了OSTaskStkInt()放到正被建立的任务堆栈中的东西。这里我们定义了堆栈是从上往下长的。

在用户建立任务的时候，用户传递任务的地址，pdata指针，任务的堆栈栈顶和任务的优先级给OSTaskCreate()和OSTaskCreateExt()。一旦用户初始化了堆栈，OSTaskStkInit()就需要返回堆栈指针所指的地址。OSTaskCreate()和OSTaskCreateExt()会获得该地址并将它保存到任务控制块（OS_TCB）中。

 

低地址内存

 

 

 

 

 

 

 

 

 

 

 

 

 

 

 
 
存储的处理器寄存器值
 
中断返回地址

 

 

 

 

 

 

 

 

 

 

 

 

 

 

 
 
处理器状态字
 
任务起始地址
 
pdata
 
高地址内存
 
堆栈指针
 
堆栈增长方向
 

图4-2 堆栈初始化（pdata通过堆栈传递）

OS_STK * OSTaskStkInit (void (*task)(void *pd), void *pdata, OS_STK *ptos,

INT16U opt)

{    unsigned int * stk;

stk    = (unsigned int *)ptos;          /* 装载堆栈指针 */

     opt++;

/* 为新任务建立堆栈 */

*--stk = (unsigned int) task;      /* pc */

*--stk = (unsigned int) task;      /* lr */

*--stk = 12;                       /* r12 */

*--stk = 11;                       /* r11 */

*--stk = 10;                       /* r10 */

*--stk = 9;                        /* r9 */

*--stk = 8;                        /* r8 */

*--stk = 7;                        /* r7 */

*--stk = 6;                        /* r6 */

*--stk = 5;                        /* r5 */

*--stk = 4;                        /* r4 */

*--stk = 3;                        /* r3 */

*--stk = 2;                        /* r2 */

*--stk = 1;                        /* r1 */

*--stk = (unsigned int) pdata;     /* r0 */

*--stk = (SUPMODE);                /* cpsr */

*--stk = (SUPMODE);               /* spsr */

return ((OS_STK *)stk);

}

 

2）OSTaskCreateHook
当用OSTaskCreate()和OSTaskCreateExt()建立任务的时候就会调用OSTaskCreateHook()。该函数允许用户或使用移植实例的用户扩展uCOS-II功能。当uCOS-II设置完了自己的内部结构后，会在调用任务调度程序之前调用OSTaskCreateHook()。该函数被调用的时候中断是禁止的。因此用户应尽量减少该函数中的代码以缩短中断的响应时间。

当OSTaskCreateHook()被调用的时候，它会收到指向已建立任务的OS_TCB的指针，这样它就可以访问所有的结构成员了。

函数原型：void OSTaskCreateHook (OS_TCB *ptcb)

3）OSTaskDelHook
当任务被删除的时候就会调用OSTaskDelHook()。该函数在把任务从uCOS-II的内部任务链表中解开之前被调用。当OSTaskDelHook()被调用的时候，它会收到指向正被删除任务的OS_TCB的指针，这样它就可以访问所有的结构成员了。OSTaskDelHook()可以来检验TCB扩展是否被建立（一个非空指针）并进行一些清除操作。

函数原型：void OSTaskDelHook (OS_TCB *ptcb)

4）OSTaskSwHook
当发生任务切换的时候就会调用OSTaskSwHook()。OSTaskSwHook()可以直接访问OSTCBCur和OSTCBHighRdy，因为它们是全局变量。OSTCBCur指向被切换出去的任务OS_TCB，而OSTCBHighRdy指向新任务OS_TCB。注意在调用OSTaskSwHook()期间中断一直是被禁止的。因此用户应尽量减少该函数中的代码以缩短中断的响应时间。

函数原型：void OSTaskSwHook (void)

5）OSTaskStatHook
OSTaskStatHook()每秒钟都会被OSTaskStat()调用一次。用户可以用OSTaskStatHook()来扩展统计功能。例如，用户可以保持并显示每个任务的执行时间，每个任务所用的CPU份额，以及每个任务执行的频率等。

函数原型：void OSTaskStatHook (void)

6）OSTimeTickHook
OSTimeTickHook()在每个时钟节拍都会被OSTaskTick()调用。实际上，OSTimeTickHook()是在节拍被uCOS-II真正处理，并通知用户的移植实例或应用程序之前被调用的。

函数原型：void OSTimeTickHook (void)

后5个函数为钩子函数，可以不加代码。只有当OS_CFG.H中的OS_CPU_HOOKS_EN被置为1时才会产生这些函数的代码。

4．用汇编语言编写4个与处理器相关的函数（OS_CPU.ASM）
1）OSStartHighRdy ()；运行优先级最高的就绪任务
OSStartHighRdy

     LDR  r4, addr_OSTCBCur       ; 得到当前任务TCB地址

     LDR  r5, addr_OSTCBHighRdy  ; 得到最高优先级任务TCB地址

 

     LDR  r5, [r5]               ; 获得堆栈指针

     LDR  sp, [r5]               ; 转移到新的堆栈中

 

     STR  r5, [r4]               ; 设置新的当前任务TCB地址

     LDMFD    sp!, {r4}           ;

     MSR  SPSR, r4

     LDMFD    sp!, {r4}           ; 从栈顶获得新的状态

     MSR  CPSR, r4               ; CPSR 处于 SVC32Mode摸式

     LDMFD    sp!, {r0-r12, lr, pc } ; 运行新的任务

2）OS_TASK_SW ()；         任务级的任务切换函数
OS_TASK_SW

     STMFD    sp!, {lr}         ; 保存 pc

     STMFD    sp!, {lr}         ; 保存 lr

     STMFD    sp!, {r0-r12}     ; 保存寄存器和返回地址

     MRS  r4, CPSR

     STMFD    sp!, {r4}         ; 保存当前的PSR

     MRS  r4, SPSR

     STMFD    sp!, {r4}         ; 保存SPSR

 

     ; OSPrioCur = OSPrioHighRdy

     LDR  r4, addr_OSPrioCur

     LDR  r5, addr_OSPrioHighRdy

     LDRB r6, [r5]

     STRB r6, [r4]

    

     ; 得到当前任务TCB地址

     LDR  r4, addr_OSTCBCur

     LDR  r5, [r4]

     STR  sp, [r5]              ; 保存sp在被占先的任务的 TCB

 

     ; 得到最高优先级任务TCB地址

     LDR  r6, addr_OSTCBHighRdy

     LDR  r6, [r6]

     LDR  sp, [r6]                    ; 得到新任务堆栈指针

     

     ; OSTCBCur = OSTCBHighRdy

     STR  r6, [r4]                   ; 设置新的当前任务的TCB地址

 

;保存任务方式寄存器

     LDMFD    sp!, {r4}

     MSR  SPSR, r4

     LDMFD    sp!, {r4}

     MSR  CPSR, r4

 

   ; 返回到新任务的上下文

     LDMFD    sp!, {r0-r12, lr, pc}

 

3）OSIntCtxSw()；中断级的任务切换函数
OSIntCtxSw

add      r7, sp, #16             ; 保存寄存器指针

LDR  sp, =IRQStack ;FIQ_STACK

mrs      r1, SPSR                ; 得到暂停的 PSR

orr      r1, r1, #0xC0           ; 关闭 IRQ, FIQ.

msr      CPSR_cxsf, r1           ; 转换模式 (应该是 SVC_MODE)

ldr      r0, [r7, #52]           ; 从IRQ堆栈中得到IRQ's LR (任务 PC)

sub      r0, r0, #4              ; 当前PC地址是(saved_LR - 4)

STMFD    sp!, {r0}               ; 保存任务 PC

STMFD    sp!, {lr}               ; 保存 LR

mov      lr, r7                  ; 保存 FIQ 堆栈 ptr in LR (转到 nuke r7)

ldmfd    lr!, {r0-r12}           ; 从FIQ堆栈中得到保存的寄存器

STMFD    sp!, {r0-r12}           ;在任务堆栈中保存寄存器

;在任务堆栈上保存PSR 和任务 PSR

MRS  r4, CPSR

bic   r4, r4, #0xC0               ; 使中断位处于使能态

STMFD    sp!, {r4}              ; 保存任务当前 PSR

MRS  r4, SPSR 

STMFD    sp!, {r4}              ; SPSR

; OSPrioCur = OSPrioHighRdy   // 改变当前程序

LDR  r4, addr_OSPrioCur

LDR  r5, addr_OSPrioHighRdy

LDRB r6, [r5]

STRB r6, [r4]

; 得到被占先的任务TCB

LDR  r4, addr_OSTCBCur

LDR  r5, [r4]

STR  sp, [r5]                ; 保存sp 在被占先的任务的 TCB

; 得到新任务 TCB 地址

LDR  r6, addr_OSTCBHighRdy

LDR  r6, [r6]

LDR  sp, [r6]                ; 得到新任务堆栈指针

; OSTCBCur = OSTCBHighRdy

STR  r6, [r4]               ; 设置新的当前任务的TCB地址

LDMFD    sp!, {r4}

MSR  SPSR, r4

LDMFD    sp!, {r4}

BIC   r4, r4, #0xC0          ; 必须退出新任务通过允许中断

MSR  CPSR, r4

LDMFD    sp!, {r0-r12, lr, pc}

 

4）OSTickISR()；时钟节拍中断

多任务操作系统的任务调度是基于时钟节拍中断的，uCOS-II也需要处理器提供一个定时器中断来产生节拍，借以实现时间的延时和期满功能。但在本系统移植uCOS-II时，时钟节拍中断的服务函数并非uCOS-II文献中提到的OSTickISR()，而直接是C语言编写的OSTimeTick()。本系统uCOS-II移植时占用的时钟资源是TIMER1。

在平台初始化函数ARMTargetInit()中，调用uHALr_InitTimers()函数初始化TIMER4相关寄存器；调用uHALr_InstallSystemTimer(void)开始系统时钟，其中通过语句SetISR_Interrupt(IRQ_TIMER4, TimerTickHandle, NULL)将TimerTickHandle函数设置为TIMER4的中断服务函数。这些函数在文件UHAL.C以及ISR.C中。

程序中必须在开始多任务调度之后再允许时钟节拍中断，即在OSStart()调用过后，uCOS-II运行的第一个任务中启动节拍中断。如果在调用OSStart()启动多任务调度之前就启动时钟节拍中断，uCOS-II运行状态可能不确定而导致崩溃，请参考uCOS-II文献移植一节。

本系统是在系统任务SYS_Task中调用uHALr_InstallSystemTimer()函数设置TIMER4的IRQ中断的，从而启动时钟节拍。SYS_Task()在文件OSAddTask.C中定义，用户不必创建，请参考本实验“完善的uCOS-II开发框架”。

完成了上述工作以后，uCOS-II就可以运行在ARM处理器上了。

1．  编写一个简单的多任务程序来测试一下移植是否成功。
为了使uCOS-II可以正常运行，除了上述必须的移植工作外，硬件初始化和配置文件也是必须的。STARTUP目录下的文件还包括中断处理，时钟，串口通信等基本功能函数。

在文件main.c中给出了应用程序的基本框架，包括初始化和多任务的创建，启动等。任务创建方法如下：

1）在程序开头定义任务堆栈，任务函数声明和任务优先级：

 

OS_STK TaskName_Stack[STACKSIZE]={0, };    //任务堆栈

void TaskName(void *Id);                        //任务函数

#define TaskName_Prio     N                //任务优先级

 

2）在main()函数中调用OSStart()函数之前用下列语句创建任务：

 

OSTaskCreate(TaskName,(void*)0,(OS_STK*)&TaskName_Stack[STACKSIZE-1],  TaskName_Prio);

 

OSTaskCreate()函数的原型是：

 

INT8U  OSTaskCreate (void (*task)(void *pd), void *p_arg, OS_STK *ptos, INT8U prio);

 

需要将任务函数TaskName，任务堆栈TaskName_Stack，任务优先级TaskName_Prio三个参数传给OSTaskCreate()函数。根据任务函数的内容决定堆栈大小，宏STACKSIZE定义为4KB，可以在此基数上乘倍。任务优先级越高，TaskName_Prio值越小；uCOS-II可以管理64个任务，由OSInit()创建的空闲任务的优先级最低为63；uCOS-II保留4个最高和4个最低优先级，用户任务可以使用其余56个优先级值。

3）编写任务函数内容：

 

void TaskName(void *Id)    

{

//添入任务初始化语句

      for(;;)

{ //添入任务循环内容

          OSTimeDly(SusPendTime);//挂起一定时间，以使其他任务可以占用CPU

        }

}

 

uCOS-II至少要有一个任务，这里已经创建一个系统任务SYS_Task， 启动系统时钟和多任务切换。

为了验证uCOS-II多任务切换的进行，再编写两个简单的任务，分别在超级终端上输出run task1和run task2。可以参考main.c的结构创建多个不同功能的任务，观察个任务的切换。

2．  编译并下载移植后的uCOS-II
所有的源代码都准备好后就可以进行编译了。在ADS环境下需要设置工程的访问路径。从菜单Edit | Debug Settings进入设置对话框，在Target | Access Paths 中选择User Paths并选上Always search user paths。然后点Add按钮添加路径ucos-ii和arch。这主要是设置编译器处理文件包含时的搜索范围。

按照映象文件下载方法实验中的操作方法将编译后的代码下载到平台的flash中。这个实验从结构上看和其他的实验没有多大区别，同样生成可执行文件system.bin。将system.bin装载到Flash中，重启平台，然后在超级终端上观察结果。